윈도우11 맞춤 항목 숨기기 & 영역 제거 방법

윈도우11 맞춤 항목 숨기기 & 영역 제거 방법

 

가. 맞춤 항목이 출력되지 않게 하는 방법

윈도우 버튼 또는 키를 누르면 위와 같이 맞춤 항목들이 출력된다. 맞춤 항목에는 개인 프라이버시를 침해하는 내용이 표시되기 때문에 해당 기능을 끄는 것이 좋다.

 

※ 맞춤 항목에 출력되는 내용

1. 최근에 추가된 앱

2. 최근에 사용한 파일

 

윈도우 버튼 또는 키> 탐색창에 "설정" 입력> 설정 앱 클릭

 

개인 설정> 시작

 

"최근에 추가된 앱 표시", "가장 많이 사용하는 앱 표시", "시작, 점프 목록 및 파일 탐색기에서 최근에 연 항목 표시" 이 3가지 항목 모두 위 사진과 같이 설정한다.

 

설정 완료 시, 위 사진과 같이 맞춤 항목이 출력되지 않는 것을 확인할 수 있다.

 

반응형

 

나. 맞춤 항목 영역 제거하는 방법

위와 같은 방법으로 맞춤 항목이 출력되지 않게 할 수 있으나, 고정됨에 출력되는 앱이 더 많이 출력될 수 있도록 맞춤 영역 자체를 제거하고 싶다면 아래의 내용을 따라하면 된다.

 

1. 윈도우 디버깅 툴 설치

https://developer.microsoft.com/ko-kr/windows/downloads/windows-sdk/

Windows SDK - Windows 앱 개발

위 사이트에 접속하여 "설치 관리자 다운로드" 버튼을 클릭해 파일을 다운받고 실행시킨다.

 

위 사진과 같이 설치를 진행한다.

 

2. 스크립트 생성

https://www.reddit.com/r/Windows11/comments/ri3zu4/batch_file_to_remove_recommended_section_of_start/

Batch File to Remove Recommended Section of Start Menu (Dev Channel only)

위 사이트에 접속하면 스크립트 생성 방법이 나와 있지만 컴퓨터를 잘 다루지 못하는 사람들은 아래의 사진을 참고하여 스크립트를 생성한다.

 

마우스 우클릭> 새로 만들기> 텍스트 문서

 

만들어진 텍스트 문서의 이름과 확장자를 "RemoveRecommended.bat"으로 변경한다.

 

RemoveRecommended.bat 파일 우클릭> 더 많은 옵션 표시> 편집

 

@echo off
echo RemoveRecommended.cmd ver. 1.1.2.3
echo This program was written for Dev Channel build 22526, but it may work with other builds

::Verifying that StartMenuExperienceHost.exe, StartMenu.dll, and cdb.exe exist
if not exist "%programfiles(X86)%\Windows Kits\10\Debuggers\x64\cdb.exe" (
  echo This program requires cdb.exe. Please download it from the Windows SDK ^(see https://docs.microsoft.com/en-us/windows-hardware/drivers/debugger^)
  exit /b
)
if not exist "%windir%\SystemApps\Microsoft.Windows.StartMenuExperienceHost_cw5n1h2txyewy\StartMenuExperienceHost.exe" (
  echo Cannot find StartMenuExperienceHost.exe
  exit /b
)
if not exist "%windir%\SystemApps\MicrosoftWindows.Client.CBS_cw5n1h2txyewy\StartMenu.dll" (
  echo Cannot find StartMenu.dll
  exit /b
)
echo StartMenuExperienceHost.exe, StartMenu.dll, and cdb.exe all exist


::Verifying that StartMenuExperienceHost.exe and StartMenu.dll are compatible with this program
Set "MD5="
for /f "skip=1 delims=" %%i in ('certutil -hashfile "%windir%\SystemApps\Microsoft.Windows.StartMenuExperienceHost_cw5n1h2txyewy\StartMenuExperienceHost.exe" MD5') do if not defined MD5 set MD5=%%i
if NOT '%MD5%'=='ca53a6568dc385e18d4039641afa9e2a' (
  echo This program is not compatible with your version of StartMenuExperienceHost.exe. Sorry :/
  exit /b
)
Set "MD5="
for /f "skip=1 delims=" %%i in ('certutil -hashfile "%windir%\SystemApps\MicrosoftWindows.Client.CBS_cw5n1h2txyewy\StartMenu.dll" MD5') do if not defined MD5 set MD5=%%i
if NOT '%MD5%'=='9547e9b1a5b8915330f0ec195e8b4e85' (
  echo This program is not compatible with your version of StartMenu.dll. Sorry :/
  exit /b
)
echo This program is compatible with your versions of StartMenuExperienceHost.exe and StartMenu.dll


::Injecting new Pinned List Height
echo bu StartMenu!winrt::StartMenu::implementation::StartInnerFrame::UpdatePinnedListHeight+f0 "r xmm1 = 0 0 3.99998 0;.detach";g | "%programfiles(X86)%\Windows Kits\10\Debuggers\x64\cdb.exe" -y srv* -plmPackage Microsoft.Windows.StartMenuExperienceHost_10.0.22526.1000_neutral_neutral_cw5n1h2txyewy -plmApp App
if not '%errorlevel%'=='-1073741819' (
  echo:  
  echo There was an error attaching CDB to StartMenuExperienceHost.exe 
  exit /b
)

echo:
echo This program has exited properly
exit /b

위 코드를 복사 붙여넣기 한다음 저장한다.

 

반응형

 

3. 스크립트 실행

RemoveRecommended.bat 파일 우클릭> 관리자 권한으로 실행

 

배치파일이 오류없이 실행될 경우 위와 같이 맞춤 항목 영역이 제거된 것을 확인할 수 있다.

※ 오류가 발생한 경우는 Windows 빌드버전이 맞지 않아 발생하는 문제이다.

※ 재부팅 하면 다시 원상복구 되므로 배치파일을 스케줄링에 등록하여 재부팅 시 배치파일이 자동으로 실행되도록 설정해 주어야 한다.

 

4. 배치파일이 자동 실행되게 하기

부팅시 배치파일이 자동으로 실행되게 하는방법은 이전 글 참조(아래 링크 클릭)

2022.01.23 - [잡학 지식] - 컴퓨터 시작 시 자동 실행되게 하는 방법

컴퓨터 시작 시 자동 실행되게 하는 방법